[空气动力快艇] 终于用ART板完成了个玩具

int oil = 8; // 油门输入
int dir = 9; // 方向输入

// #1
int pwm = 7; // PWM输出引脚定义
int in1 = 6; // 电机方向使能1
int in2 = 5; // 电机方向使能2

int dir_value = 0; // 记录当前方向值， 0:停止 >0:前进 <0:后退

// 设置方向
void set_dir(int value)
{
    if(value == 0)
    {
        digitalWrite(in1, LOW);
        digitalWrite(in2, LOW);
        return;
    }

    if(value > 0)
    {
        digitalWrite(in1, LOW);
        digitalWrite(in2, HIGH);
    }
    else
    {
        digitalWrite(in1, HIGH);
        digitalWrite(in2, LOW);
    }
}

// the setup routine runs once when you press reset:
void setup()
{
    // initialize the digital pin as an output.
    //Serial.begin(9600);

    pinMode(oil, INPUT);
    pinMode(dir, INPUT);

    pinMode(in1, OUTPUT);
    pinMode(in2, OUTPUT);
    set_dir(1);
}

// the loop routine runs over and over again forever:
void loop()
{
    int oil_value;

    // 读取方向输入
    {
        int new_dir;
        if(pulseIn(dir, HIGH) > 1700)
        {
            new_dir = 1;
        }
        else
        {
            new_dir = 0;
        }

        if(new_dir != dir_value)
        {
            dir_value = new_dir;
            set_dir(0);
            delay(300);

            if( dir_value == 0)
            {
                set_dir(1);
            }
            else
            {
                set_dir(-1);
            }
        }
    }

    // 读取油门输入,油门值是反向
    oil_value = pulseIn(oil, HIGH);
    //Serial.println(oil_value);

    // 为了比较容易停止，只要值大于1850就算到底。
    if(oil_value > 1850)
    {
        oil_value = 1850;
    }

    // PWM值范围是 0~255。换算之
    oil_value = oil_value - (1850 - (255 * 3));
    oil_value = (255 * 3) - oil_value;
    oil_value = oil_value / 3;

    // 限制一下最大值。
    oil_value = oil_value / 3;

    // 调整最小油门，利于电机启动。
    if((oil_value > 0) && (oil_value < 20))
    {
        oil_value = 20;
    }

    // 油门输出
    analogWrite(pwm, oil_value);
    //Serial.println(oil_value);

    delay(10);
}

const int analogInPin = 0;  // Analog input pin that the potentiometer is attached to
const int LED_Pin = 12;  // Analog input pin that the potentiometer is attached to

int sensorValue = 0;        // value read from the pot

void setup()
{
    pinMode(LED_Pin, OUTPUT);
    digitalWrite(LED_Pin, LOW);
}

void loop()
{
    // read the analog in value:
    sensorValue = analogRead(analogInPin);

    //rt_kprintf("AD:%u
", sensorValue);

    if(sensorValue < 2700) // 7V
    {
        digitalWrite(LED_Pin, HIGH);
        delay(80);
        digitalWrite(LED_Pin, LOW);
        delay(100);
        digitalWrite(LED_Pin, HIGH);
        delay(80);
        digitalWrite(LED_Pin, LOW);
        delay(2000);
    }
    else
    {
        digitalWrite(LED_Pin, HIGH);
        delay(200);
        digitalWrite(LED_Pin, LOW);
        delay(5000);
    }
}

查看更多