初探STM32F4 CCM在RT-Studio下的分配 5.00

发布于 2022-04-10 16:33:08 浏览：4841 订阅该版

[tocm]

STM32F4系列内部有64KB CCM（Core Coupled Memory），加上内部192KB RAM，合计256KB。但是，CCM RAM在RT-Studio中并未使用。CCM部分很特殊，挂在D-Bus上，只能通过CPU访问，不能被DMA访问，官方为了适配所有平台，默认没有使用这部分CCM。

在MDK工程中新增CCM比较方便，简单编辑sct文件即可。但是，与MDK不同，RT-Studio使用gcc编译代码。

近期项目开发中RAM不够，需要开启CCM。在本论坛查了一些问题/文章，都不能完全解决`同时在CCM中使用未初始化变量和初始化变量`的需求；官方AN4296文档的配置方式也会导致bin文件过大。因此，本文在下述参考链接的基础上，提出三种简单修改lds的方案，分别对应：`仅用于未初始化变量、仅用于初始化变量、同时支持未初始化和初始化变量`三种使用场景。

简单说明一下，论坛中lds代码高亮是使用\```c， 最终查看了网页源代码才了解。

本文参考链接：

[RT-Thread-link.lds修改使满足CCM RAM，但数据出错RT-Thread问答社区 - RT-Thread](https://club.rt-thread.org/ask/question/425240.html)

[RT-Thread-STM32F4在RT-Thread Studio中使用CCM SRAMRT-Thread问答社区 - RT-Thread](https://club.rt-thread.org/ask/question/423945.html)

[RT-Thread-rtthread studio生成hex文件正常，bin文件太大RT-Thread问答社区 - RT-Thread](https://club.rt-thread.org/ask/question/430211.html)

[OpenSTM32 Community Site | Using CCM Memory](https://www.openstm32.org/Using%2BCCM%2BMemory)

## 1 第一种CCM添加方案：未初始化变量

> 第一种CCM添加方案仅仅支持将未初始化变量放置在CCM RAM中，不能在声明变量时赋初始值。

1.创建工程，将红色处按照电路实际情况进行修改。

![image-20220409230614068.png](https://oss-club.rt-thread.org/uploads/20220410/53f98ec86a3520fa3aa11657aeb51073.png.webp)

2.删除部分main函数代码，避免打印输出影响查看后续的打印输出。编译工程，得到Flash和RAM的占用。

![image-20220409230824509.png](https://oss-club.rt-thread.org/uploads/20220410/f69ddf34374b19b6bc24617eee8bb85e.png.webp)

3.打开并查看lds文件

![image-20220409231049839.png](https://oss-club.rt-thread.org/uploads/20220410/35b19bd892a68fa820018d36dcfe2547.png.webp)

4.找到`linkscripts->STM32F429VI`目录下的lds文件，使用文本编辑器编辑，增加一行CCM的描述，如第5行代码所示。

```c
MEMORY
{
    ROM (rx) : ORIGIN = 0x08000000, LENGTH =  2048k /* 2048K flash */
    RAM (rw) : ORIGIN = 0x20000000, LENGTH =  192k /* 192K sram */
	CCM (rw) : ORIGIN = 0x10000000, LENGTH =  64k  /* 64K ccm sram */
}
```

5.关闭lds文件，重新打开，确认CCM已经添加

![image-20220409231448385.png](https://oss-club.rt-thread.org/uploads/20220410/3f2e4f4b0586e71bd56057d0a1ff80a9.png)

6.在lds文件中添加`.ccm section`的描述，位于.data section上方。

```c
.ccm :
{
	. = ALIGN(4);
	_sccm = .;      /*create a global symbol at ccmram start */
	*(.ccm)         /* .ccm sections */
	*(.ccm*)        /* .ccm* sections */
	. = ALIGN(4);
	_eccm = .;  /*create a global symbol at ccmram end */
} >CCM
```

![image-20220410124516037.png](https://oss-club.rt-thread.org/uploads/20220410/75caca11a2bdec322185599bdd392a1c.png.webp)

7.修改main.c代码，使用`__attribute__`关键词增加几个变量到.ccm section。

```c
__attribute__((section(".ccm"))) rt_uint8_t array[4];
__attribute__((section(".ccm"))) rt_uint8_t *ptr;

int main(void)
{
    ptr = array;
    for(rt_uint8_t i = 0; i < 4; i++)
    {
        *ptr = 7 + i;
        ptr++;
    }
    rt_kprintf("ptr = 0x%08x, stores in 0x%08x\n", ptr, &ptr);
    for(rt_uint8_t i = 0; i < 4; i++)
    {
        rt_kprintf("array[%d] = %d\n",i,array[i]);
    }
    return RT_EOK;
}
```

8.查看Debug目录下的`rtthread.map`文件，找到.ccm部分。显然，array和ptr都被分配到了CCM RAM。

![image-20220410124623690.png](https://oss-club.rt-thread.org/uploads/20220410/b2cfdcc4e05841633c49f09dec2ecb94.png.webp)

9.下载程序，观察结果。

![image-20220410124950203.png](https://oss-club.rt-thread.org/uploads/20220410/aeb5948c42b50531b4c096a225e91898.png)

显然，此时数据被写入到了array，且ptr指向一切正常。`结果中，ptr=0x10000004`是因为在for循环中自增了4次。

11.打开Debug目录，发现rtthread.bin文件太大，达到了`131073KB`。

![image-20220410125144786.png](https://oss-club.rt-thread.org/uploads/20220410/2077ad9401c1f4971b098903c555efbe.png)

12.再次修改.ccm部分，添加`NoLOAD`关键词后重新编译，bin文件大小正常。

```c
.ccm (NOLOAD):
{
	. = ALIGN(4);
	_sccm = .;      /*create a global symbol at ccmram start */
	*(.ccm)         /* .ccm sections */
	*(.ccm*)        /* .ccm* sections */
	. = ALIGN(4);
	_eccm = .;  /*create a global symbol at ccmram end */
} >CCM
```

![image-20220410125327132.png](https://oss-club.rt-thread.org/uploads/20220410/f497ff642dec148c754c6944c093dc93.png)

> **重要说明：**这种方式，只支持将未初始化变量放置在.ccm中。在声明时，任何对.ccm中的变量赋初始值的做法都是不对的，哪怕将将变量的初始值赋值为0也不行。

## 2 第二种CCM添加方案：初始化变量

>  第二种CCM添加方案，支持对存储在CCM RAM中的变量赋初始值。

1.修改.ccm和.data的lds部分

```c
_siccm = LOADADDR(.ccm);
.ccm :
{
    . = ALIGN(4);
    _sccm = .;      /*create a global symbol at ccmram start */
    *(.ccm)         /* .ccm sections */
    *(.ccm*)        /* .ccm* sections */
    . = ALIGN(4);
    _eccm = .;  /*create a global symbol at ccmram end */
} >CCM AT>ROM

/* .data section which is used for initialized data */
_sidata = LOADADDR(.data);
.data :
{
    . = ALIGN(4);
    /* This is used by the startup in order to initialize the .data secion */
    _sdata = . ;

*(.data)
    *(.data.*)
    *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
    KEEP(*(SORT(.dtors.*)))
    KEEP(*(.dtors))
    PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
    /* This is used by the startup in order to initialize the .data secion */
    _edata = . ;
} >RAM AT>ROM
```

![image-20220410131244208.png](https://oss-club.rt-thread.org/uploads/20220410/215283ce15be079526c056a57144b6f7.png.webp)

2.修改启动代码

启动代码`startup_stm32f429xx.s`位于`libraries->CMSIS->Device->ST->STM32F4xx->Source->Templates->gcc`目录下，隐藏较深。

原始的启动代码只对.data区进行了初始化，我们现在需要对.ccm区也进行初始化。

Step1. 在原始的启动代码的`.word  _ebss`行后添加如下代码，从lds中引入\_sciccm, \_sccm和 \_eccm。

```assembly
/* start address for the initialization values of the .data ccm section.
defined in linker script */
.word  _siccm
/* start address for the .ccm section. defined in linker script */
.word  _sccm
/* end address for the .ccm section. defined in linker script */
.word  _eccm
```

Step2. 在原始的启动代码的`bcc  CopyDataInit`和`ldr  r2, =_sbss`两行中间插入如下代码，对.ccm中的变量进行初始化，即，从Flash中搬运至CCM RAM。简单添加了注释，很好理解。

```assembly
/* Copy the data CCM segment initializers from flash to SRAM */
  movs  r1, #0          /* 起始计数 */
  b  LoopCopyCCMInit    /* 调用LoopCopyCCMInit */

CopyCCMInit:
  ldr  r3, =_siccm     /* Flash中存储的CCM RAM变量初始值的起始地址 */
  ldr  r3, [r3, r1]    /* r3 <-[r3+r1] */
  str  r3, [r0, r1]    /* [r0 + r1] <- r3 */
  adds  r1, r1, #4     /* 偏移量加4*/

LoopCopyCCMInit:
  ldr  r0, =_sccm      /* .ccm section的起始地址 */
  ldr  r3, =_eccm      /* .ccm section的终止地址 */
  adds  r2, r0, r1     /* r2 <- 指针加偏移量*/
  cmp  r2, r3          /* 指针是否已经指向了终止地址？ */
  bcc  CopyCCMInit
```

3.修改main.c，编译、下载、观察运行结果

```c
__attribute__((section(".ccm"))) rt_uint8_t array[4] = {1,2,3,4};
__attribute__((section(".ccm"))) rt_uint8_t *ptr = array;

int main(void)
{
    rt_kprintf("ptr = 0x%08x, stores in 0x%08x\n", ptr, &ptr);
    for(rt_uint8_t i = 0; i < 4; i++)
    {
        rt_kprintf("array[%d] = %d\n",i,array[i]);
    }
    return RT_EOK;
}
```

![image-20220410132505367.png](https://oss-club.rt-thread.org/uploads/20220410/0765de83f594c23b3c22c75cafd7899d.png)

记住`55048`这个数据，很快会用到。

![image-20220410131752727.png](https://oss-club.rt-thread.org/uploads/20220410/8671a5ae2aa4bd37d12caaf4cd76cf82.png)

显然，此时在.ccm section中的变量已经被成功赋初始值了。

4.如果在main.c再添加一个大型未初始化的数组，会发生什么？

```c
__attribute__((section(".ccm"))) rt_uint8_t bigger_array[1024];
```

![image-20220410132706844.png](https://oss-club.rt-thread.org/uploads/20220410/fd7b70c7e1b5c1203918ea1a3c3add88.png.webp)

编译后，Flash容量变成了`65288`。显然，`65288 - 55048 = 10240`。

bigger_array虽然没有被初始化，但是它被分配在.ccm section，按照lds的约束和修改后的启动代码，STM32启动后，要从Flash中搬运10K的数据到该数组。显然，这与我们的需求并不符合。我们最终是需要将CCM配置成既支持.data，也支持.bss的方式。

## 3 第三种CCM方案：共存

> 第三种CCM方案，既支持初始化变量放置在CCM中，也支持未初始化变量放置在CCM中。解决思路是在CCM中增加两个Section，一个用于存放.data数据，一个用于存放.bss数据。

1.在上述两种方式的指导下，我们可以迅速在.ccm seciton后方再次添加一个.ccmbss section。

```c
.ccmbss (NOLOAD):
{
	. = ALIGN(4);
	_sccmbss = .;   /*create a global symbol at ccmram start */
	*(.ccmbss)      /* .data sections */
	*(.ccmbss*)     /* .data* sections */
	. = ALIGN(4);
	_eccmbss = .;  /*create a global symbol at ccmram end */
} >CCM
```

2.修改main.c

```c
__attribute__((section(".ccm"))) rt_uint8_t array[4] = {1,2,3,4};
__attribute__((section(".ccm"))) rt_uint8_t *ptr = array;
__attribute__((section(".ccmbss"))) rt_uint8_t bigger_array[10*1024];

int main(void)
{
    rt_kprintf("ptr = 0x%08x, stores in 0x%08x\n", ptr, &ptr);
    for(rt_uint8_t i = 0; i < 4; i++)
    {
        bigger_array[i] = i; /* 假装使用了bigger_array, 防止编译器优化掉这个数组*/
        rt_kprintf("array[%d] = %d, bigger_array[%d] = %d\n",
                i,array[i],
                i,bigger_array[i]);

}
    return RT_EOK;
}
```

3.编译，查看map文件，查看Flash占用，新增的10K并未占用Flash空间，bin文件也正常。

![image-20220410141755291.png](https://oss-club.rt-thread.org/uploads/20220410/3b6d53f1acc5b2c675b0070e6f621e44.png.webp)

![image-20220410135436743.png](https://oss-club.rt-thread.org/uploads/20220410/6704c4c43551006b761b18e806ba0e83.png)

![image-20220410135524440.png](https://oss-club.rt-thread.org/uploads/20220410/cc1eef4c069975a242d650b16d65023a.png)

![image-20220410135056130.png](https://oss-club.rt-thread.org/uploads/20220410/6a1ddffc9e2c7f56c50628475d16794f.png)

4.再次修改bigger_array的存放位置，放置在.ccm，显然，此时Flash会增大10K。并且，在初始化时，启动代码会对这10K RAM空间进行初始化。

![image-20220410142015766.png](https://oss-club.rt-thread.org/uploads/20220410/4ee235b15466fcc436d99731810500cf.png.webp)

5.最后附上完整的lds文件，Happy RTT!

```c
/*
 * linker script for STM32F429VI with GNU ld
 */

/* Program Entry, set to mark it as "used" and avoid gc */
MEMORY
{
    ROM (rx) : ORIGIN = 0x08000000, LENGTH =  2048k /* 2048K flash */
    RAM (rw) : ORIGIN = 0x20000000, LENGTH =  192k /* 192K sram */
	CCM (rw) : ORIGIN = 0x10000000, LENGTH = 64k /*64K ccm ram*/
}
ENTRY(Reset_Handler)
_system_stack_size = 0x400;

SECTIONS
{
    .text :
    {
        . = ALIGN(4);
        _stext = .;
        KEEP(*(.isr_vector))            /* Startup code */

. = ALIGN(4);
        *(.text)                        /* remaining code */
        *(.text.*)                      /* remaining code */
        *(.rodata)                      /* read-only data (constants) */
        *(.rodata*)
        *(.glue_7)
        *(.glue_7t)
        *(.gnu.linkonce.t*)

/* section information for finsh shell */
        . = ALIGN(4);
        __fsymtab_start = .;
        KEEP(*(FSymTab))
        __fsymtab_end = .;

. = ALIGN(4);
        __vsymtab_start = .;
        KEEP(*(VSymTab))
        __vsymtab_end = .;

/* section information for utest */
        . = ALIGN(4);
        __rt_utest_tc_tab_start = .;
        KEEP(*(UtestTcTab))
        __rt_utest_tc_tab_end = .;

/* section information for at server */
        . = ALIGN(4);
        __rtatcmdtab_start = .;
        KEEP(*(RtAtCmdTab))
        __rtatcmdtab_end = .;
        . = ALIGN(4);

/* section information for initial. */
        . = ALIGN(4);
        __rt_init_start = .;
        KEEP(*(SORT(.rti_fn*)))
        __rt_init_end = .;

. = ALIGN(4);

PROVIDE(__ctors_start__ = .);
        KEEP (*(SORT(.init_array.*)))
        KEEP (*(.init_array))
        PROVIDE(__ctors_end__ = .);

. = ALIGN(4);

_etext = .;
    } > ROM = 0

/* .ARM.exidx is sorted, so has to go in its own output section.  */
    __exidx_start = .;
    .ARM.exidx :
    {
        *(.ARM.exidx* .gnu.linkonce.armexidx.*)

/* This is used by the startup in order to initialize the .data secion */
        _sidata = .;
		_siccmram = .;
    } > ROM
    __exidx_end = .;
	
    /* .data section which is used for initialized data */
	_sidata = LOADADDR(.data);
    .data :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _sdata = . ;

*(.data)
        *(.data.*)
        *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
        KEEP(*(SORT(.dtors.*)))
        KEEP(*(.dtors))
        PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _edata = . ;
    } >RAM AT > ROM
	
	 _siccm = LOADADDR(.ccm);
	.ccm :
	{
		. = ALIGN(4);
		_sccm = .;   /*create a global symbol at ccmram start */
		*(.ccmram)      /* .data sections */
		*(.ccmram*)     /* .data* sections */
		. = ALIGN(4);
		_eccm = .;  /*create a global symbol at ccmram end */
	} >CCM AT>ROM
	
	.ccmbss (NOLOAD):
	{
		. = ALIGN(4);
		_sccmbss = .;   /*create a global symbol at ccmram start */
		*(.ccmbss)      /* .data sections */
		*(.ccmbss*)     /* .data* sections */
		. = ALIGN(4);
		_eccmbss = .;  /*create a global symbol at ccmram end */
	} >CCM

.stack : 
    {
        . = ALIGN(4);
        _sstack = .;
        . = . + _system_stack_size;
        . = ALIGN(4);
        _estack = .;
    } >RAM

__bss_start = .;
    .bss :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _sbss = .;

*(.bss)
        *(.bss.*)
        *(COMMON)

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _ebss = . ;
        
        *(.bss.init)
    } > RAM
    __bss_end = .;

_end = .;

/* Stabs debugging sections.  */
    .stab          0 : { *(.stab) }
    .stabstr       0 : { *(.stabstr) }
    .stab.excl     0 : { *(.stab.excl) }
    .stab.exclstr  0 : { *(.stab.exclstr) }
    .stab.index    0 : { *(.stab.index) }
    .stab.indexstr 0 : { *(.stab.indexstr) }
    .comment       0 : { *(.comment) }
    /* DWARF debug sections.
     * Symbols in the DWARF debugging sections are relative to the beginning
     * of the section so we begin them at 0.  */
    /* DWARF 1 */
    .debug          0 : { *(.debug) }
    .line           0 : { *(.line) }
    /* GNU DWARF 1 extensions */
    .debug_srcinfo  0 : { *(.debug_srcinfo) }
    .debug_sfnames  0 : { *(.debug_sfnames) }
    /* DWARF 1.1 and DWARF 2 */
    .debug_aranges  0 : { *(.debug_aranges) }
    .debug_pubnames 0 : { *(.debug_pubnames) }
    /* DWARF 2 */
    .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
    .debug_abbrev   0 : { *(.debug_abbrev) }
    .debug_line     0 : { *(.debug_line) }
    .debug_frame    0 : { *(.debug_frame) }
    .debug_str      0 : { *(.debug_str) }
    .debug_loc      0 : { *(.debug_loc) }
    .debug_macinfo  0 : { *(.debug_macinfo) }
    /* SGI/MIPS DWARF 2 extensions */
    .debug_weaknames 0 : { *(.debug_weaknames) }
    .debug_funcnames 0 : { *(.debug_funcnames) }
    .debug_typenames 0 : { *(.debug_typenames) }
    .debug_varnames  0 : { *(.debug_varnames) }
}
```

## 4 小结

- .bss：存放未初始化（未初始化或者0初始化的全局变量和静态局部变量）的数据；
- .data：存放已初始化（非零初始化的全局变量和静态局部变量）的数据。

其实，从第三种解决方案和启动代码中可以进一步发现，本文第三种解决方案的.ccmbss部分并没有对未初始化变量进行清0操作。官方自带启动代码中，在LoopFillZerobss函数中对.bss区的数据进行了清0操作。如果需要对.ccmbss中的数据进行清零，可以参照LoopFillZerobss进一步修改启动代码。限于篇幅，也比较简单，这部分就不再展开了。

附上个人公众号，欢迎关注：
![LCRQR.jpg](https://oss-club.rt-thread.org/uploads/20220410/08256c6c91d83e941432ccff0eaaaf3e.jpg)

aozima 打赏了 5.00 元 2022-04-24 21:33:05

30 条评论

crystal266 2022-04-10

嵌入式

lchnu 2022-04-10

Witness, Understand, Skill

pkokoc 2022-04-11

这家伙很懒，什么也没写！

xdj999 2022-04-11

这家伙很懒，什么也没写！

lchnu 2022-04-11

Witness, Understand, Skill

lchnu 2022-04-18

Witness, Understand, Skill

xiaoyu 2022-04-24

这家伙很懒，什么也没写！

xiaoyu 2022-04-24

这家伙很懒，什么也没写！

lchnu 2022-04-24

Witness, Understand, Skill

xiaoyu 2022-04-25

这家伙很懒，什么也没写！

lchnu 2022-04-25

Witness, Understand, Skill

@xiaoyu 
程序 = .text + .data + .bss, 其中：
1. .text是代码+全局变量的初始值，存储在Flash中；
2. .data是初始化的全局变量，static类型的函数内局部变量，地址位于RAM中。在启动代码中，要对这部分变量进行赋值，如MDK下的__main函数，如rt-studio（gcc）下的startup.s中的_sdata和_edata之间的搬运；
3. .bss未初始化的变量，或者初值为0的变量，也是存放在RAM中。你可以阅读rt-studio下创建的工程启动代码，你会发现，.bss的变量实际是在启动代码中通过循环，都变成0了。至于，MDK中的__main实现细节，到底有没有处理.bss和其他section的变量，我就不是太清楚了，但肯定没有从ROM中搬运至RAM。

Q：为什么.text在Flash，.data和.bss在RAM？
A：阅读一下lds文件，或者MDK下的Scatter文件，你就能看到它们的定位。

C程序是静态程序，编译-链接之后，所有全局变量的地址、函数的地址都被确定了。

现在可以回答你的问题了：
1. 第一个正点原子的截图。testsram数组通过关键字__attribute__，指定了其绝对地址在0xC0000000，编译之后，这个数组的存放地址就被决定了。

系统启动后，在main函数，或者其他函数中调用这个fsmc_sdram_test之前，肯定完成了FSMC的初始化，自然不会有任何问题。这个函数是先写再读，在0xC00000000开始的一段内存中，原始数据是什么根本不重要。testsram是一个典型的未初始化全局变量。运行到fsmc_sdram_test函数之前，你不妨理解成，程序并没有对这个数组进行任何操作，只是初始化了FSMC接口。

`你可以试试在FSMC初始化之前调用这个函数，不会得到正确结果`。

2. 第二个野火的截图。这是一个MDK工程的启动代码，你给的信息不充分，看不到在哪里调用了FSMC_SRAM_Init，我也没有野火的工程。

但是，就如我上一个问题中给你的答复一样，野火的工程将初始化的全局变量放在了SDRAM中，就一定是在__main之前完成了对FSMC_SRAM_Init的调用，在搬运数据到SDRAM前，肯定要对接口进行初始化，不然无法读取和写入。`同样，你也可以试试，修改启动代码，不调用这个FSMC_SRAM_Init，打印这两个数组的内容，肯定不会是初始化的值。测试之前，记得断电再来。`

xiaoyu 2022-04-25

这家伙很懒，什么也没写！

lchnu 2022-04-25

Witness, Understand, Skill

@xiaoyu

你说的对，不初始化接口，是不可能对0xC0000000地址进行操作的。

1. 正点原子的例程，定位在0xC0000000的数组testsram，你可以理解成，既不是.data，也不是.bss，MDK的__main函数并没有对它做任何操作。`testsram所在的section，是我们通过__attribute__关键词额外添加的一段。`

main函数的流程，一定是调用了MX_FSMC_Init，即对于FSMC硬件进行了初始化之后，才调用了fsmc_sdram_test函数。`只有先初始化硬件接口，然后读写0xC0000000开始的地址，才能让STM32的Addr、Data、RD/WR引脚上出现对应的信号，真正访问到SDRAM。`

2. 如果是在RT-Studio下，使用Gcc编译，需要将testsram放置在0xC0000000开始的地址，操作方式和MDK中一致。区别在于，要修改lds文件，将0xC0000000一段地址空间命名为，如SRAM；然后在SRAM部分新增一些section。

如下方就在0xC00000000开始的地址段，开辟一段256KB的SDRAM，并且将它自由命名成了user section。我们就可以在user section中放置，类似于正点例程的数组testsram。`这个user section既不是.data, 也不是.bss。我们拥有对它自由操作的权力。`

```c
uint8_t testsram[2048] __attribute__((section("user")));
```

```c
MEMORY
{
    ROM (rx) : ORIGIN = 0x08000000, LENGTH =  2048k /* 2048K flash */
    RAM (rw) : ORIGIN = 0x20000000, LENGTH =  192k  /* 192K sram */
    SDRAM (rw) : ORIGIN = 0xC0000000, LENGTH = 256k /*256K SDRAM*/
}

.user (NOLOAD):
{
	. = ALIGN(4);
	_suser = .;   /*create a global symbol at user start */
	*(.user)      /* .user sections */
	*(.user.*)     /* .user * sections */
	. = ALIGN(4);
	_euser = .;  /*create a global symbol at user end */
} >SDRAM
....
```

最后，以STM32F429 CSP 0.2.2版本的启动代码为例，我在下方的启动代码中，增加的中文注释是针对.data段的数据，将初始化的值从Flash中搬运到RAM中；.bss段的处理没有标注注释，道理是一样的，所有.bss数据清零。因此，你可以认为，官方启动代码中，对.data段进行了初始化，对.bss段进行了清零。
```asm
    .section  .text.Reset_Handler
  .weak  Reset_Handler
  .type  Reset_Handler, %function
Reset_Handler: 
  ldr   sp, =_estack       /* set stack pointer */
 
/* Copy the data segment initializers from flash to SRAM */  
  movs  r1, #0
  b  LoopCopyDataInit      /* 从Flash搬运数据到RAM的.data段*/

CopyDataInit:
  ldr  r3, =_sidata        /* .data数据在FLASH中存储的基址*/
  ldr  r3, [r3, r1]        /* 以r1为偏移，取出数据，存在R3*/
  str  r3, [r0, r1]        /* 存放到RAM中的.data变量*/
  adds  r1, r1, #4         /* 偏移加4*/
    
LoopCopyDataInit:
  ldr  r0, =_sdata         /*.data 变量的Start地址*/
  ldr  r3, =_edata         /*.data 变量的End地址*/
  adds  r2, r0, r1          
  cmp  r2, r3              /*.data是否全部处理完毕？*/
  bcc  CopyDataInit        /*.data没有搬运完毕，继续搬运Flash中数据到.data RAM中*/
  ldr  r2, =_sbss          /*.data搬运完毕，开始处理.bss段 */ 
  b  LoopFillZerobss       /*下面同理，所有.bss数据清零*/
/* Zero fill the bss segment. */  
FillZerobss:
  movs  r3, #0
  str  r3, [r2], #4
    
LoopFillZerobss:
  ldr  r3, = _ebss
  cmp  r2, r3
  bcc  FillZerobss

/* Call the clock system intitialization function.*/
  bl  SystemInit   
/* Call static constructors */
    /* bl __libc_init_array */
/* Call the application's entry point.*/
  bl  entry
  bx  lr

```

xiaoyu 2022-04-25

这家伙很懒，什么也没写！

lchnu 2022-04-25

Witness, Understand, Skill

xiaoyu 2022-04-25

这家伙很懒，什么也没写！

lchnu 2022-04-25

Witness, Understand, Skill

xiaoyu 2022-04-25

这家伙很懒，什么也没写！

xiaoyu 2022-04-25

这家伙很懒，什么也没写！

lchnu 2022-04-25

Witness, Understand, Skill

lchnu 2022-09-13

Witness, Understand, Skill

iron_cdw 2023-04-13

这家伙很懒，什么也没写！

- 大佬 看了你的文章 我试着操作了一下，第一种方式很顺利。问题出现在了第二种 如下：编译会报错

```c
arm-none-eabi/bin/ld.exe: section .data LMA [08061018,08061aff] overlaps section .ccm LMA [08061018,0806101f]
```
下面是我的link.lds文件中相关的部分

```c
    /* .ARM.exidx is sorted, so has to go in its own output section.  */
    __exidx_start = .;
    .ARM.exidx :
    {
        *(.ARM.exidx* .gnu.linkonce.armexidx.*)

/* This is used by the startup in order to initialize the .data secion */
        _sidata = .;
    } > ROM
    __exidx_end = .;

_siccm = LOADADDR(.ccm);
    .ccm :
    {
        . = ALIGN(4);
        _sccm = .;   /*create a global symbol at ccmram start */
        *(.ccm)      /* .data sections */
        *(.ccm*)     /* .data* sections */
        . = ALIGN(4);
        _eccm = .;  /*create a global symbol at ccmram end */
    } >CCM AT>ROM

/* .data section which is used for initialized data */

.data : AT (_sidata)
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _sdata = . ;

*(.data)
        *(.data.*)
        *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
        KEEP(*(SORT(.dtors.*)))
        KEEP(*(.dtors))
        PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _edata = . ;
    } >RAM
```
 希望大佬有时间可以帮忙分析下

lchnu 2023-04-14

Witness, Understand, Skill

li460135301 2023-04-20

这家伙很懒，什么也没写！

iron_cdw 2023-04-23

这家伙很懒，什么也没写！

lchnu 2023-04-23

Witness, Understand, Skill

lchnu 2023-04-26

Witness, Understand, Skill

[@iron_cdw](https://club.rt-thread.org/u/3269fe19eb372f63)

你好，你的问题我已经解决了。文章中第二种方法是正确的，但是中间过程部分，我有些没写出来，导致你出现了Overlap的问题。

附上我的完整lds文件和main.c文件。注意，修改后部分内容indent部分都是顶格写的，方便你查阅。同时，我也截图给你标注出来。

## 第二种方案

- 按照图中批注修改原始的.data，尤其注意删除AT(\_sidata)、添加AT > ROM等
- CCM .data部分复制原文即可。

** 第二种方案的lds文件 **
```c
/*
 * linker script for STM32F429VI with GNU ld
 */

/* Program Entry, set to mark it as "used" and avoid gc */
MEMORY
{
    ROM (rx) : ORIGIN = 0x08000000, LENGTH =  2048k /* 2048K flash */
    RAM (rw) : ORIGIN = 0x20000000, LENGTH =  192k /* 192K sram */
    CCM (rw) : ORIGIN = 0x10000000, LENGTH =  64k  /* 64K ccm sram */
}
ENTRY(Reset_Handler)
_system_stack_size = 0x400;

SECTIONS
{
    .text :
    {
        . = ALIGN(4);
        _stext = .;
        KEEP(*(.isr_vector))            /* Startup code */

/* section information for finsh shell */
        . = ALIGN(4);
        __fsymtab_start = .;
        KEEP(*(FSymTab))
        __fsymtab_end = .;

. = ALIGN(4);
        __vsymtab_start = .;
        KEEP(*(VSymTab))
        __vsymtab_end = .;

/* section information for utest */
        . = ALIGN(4);
        __rt_utest_tc_tab_start = .;
        KEEP(*(UtestTcTab))
        __rt_utest_tc_tab_end = .;

/* section information for at server */
        . = ALIGN(4);
        __rtatcmdtab_start = .;
        KEEP(*(RtAtCmdTab))
        __rtatcmdtab_end = .;
        . = ALIGN(4);

/* section information for initial. */
        . = ALIGN(4);
        __rt_init_start = .;
        KEEP(*(SORT(.rti_fn*)))
        __rt_init_end = .;

. = ALIGN(4);

PROVIDE(__ctors_start__ = .);
        KEEP (*(SORT(.init_array.*)))
        KEEP (*(.init_array))
        PROVIDE(__ctors_end__ = .);

. = ALIGN(4);

_etext = .;
    } > ROM = 0

/* .ARM.exidx is sorted, so has to go in its own output section.  */
    __exidx_start = .;
    .ARM.exidx :
    {
        *(.ARM.exidx* .gnu.linkonce.armexidx.*)

/* This is used by the startup in order to initialize the .data secion */
/*_sidata = .;*/
    } > ROM
    __exidx_end = .;

_siccm = LOADADDR(.ccm);
.ccm :
{
    . = ALIGN(4);
    _sccm = .;      /*create a global symbol at ccmram start */
    *(.ccm)         /* .ccm sections */
    *(.ccm*)        /* .ccm* sections */
    . = ALIGN(4);
    _eccm = .;  /*create a global symbol at ccmram end */
} >CCM AT>ROM

/* .data section which is used for initialized data */
_sidata = LOADADDR(.data);
.data :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _sdata = . ;

*(.data)
        *(.data.*)
        *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
        KEEP(*(SORT(.dtors.*)))
        KEEP(*(.dtors))
        PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _edata = . ;
    } >RAM AT > ROM

.stack : 
    {
        . = ALIGN(4);
        _sstack = .;
        . = . + _system_stack_size;
        . = ALIGN(4);
        _estack = .;
    } >RAM

__bss_start = .;
    .bss :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _sbss = .;

*(.bss)
        *(.bss.*)
        *(COMMON)

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _ebss = . ;
        
        *(.bss.init)
    } > RAM
    __bss_end = .;

_end = .;

```

** 第二种方案的main.c **

```c
#include <rtthread.h>

#define DBG_TAG "main"
#define DBG_LVL DBG_LOG
#include <rtdbg.h>

__attribute__((section(".ccm"))) rt_uint8_t array[4] = {1,2,3,4};
__attribute__((section(".ccm"))) rt_uint8_t *ptr = array;

int main(void)
{
    ptr = array;

rt_kprintf("ptr = 0x%08x, stores in 0x%08x\n", ptr, &ptr);

for(rt_uint8_t i = 0; i < 4; i++)
    {
        rt_kprintf("array[%d] = %d\n",i,array[i]);
    }
    return RT_EOK;
}
```

** 第二种方案结果 **

![screenshot_image.png](https://oss-club.rt-thread.org/uploads/20230426/5cbc7a5c75ce4c94de066c62c84511ba.png.webp)

![screenshot_image.png](https://oss-club.rt-thread.org/uploads/20230426/1735baec53acba62b8e8925918d2f45f.png.webp)

## 第三种共存方案

** 第三种方案完整lds文件**
```c
/*
 * linker script for STM32F429VI with GNU ld
 */

/* Program Entry, set to mark it as "used" and avoid gc */
MEMORY
{
    ROM (rx) : ORIGIN = 0x08000000, LENGTH =  2048k /* 2048K flash */
    RAM (rw) : ORIGIN = 0x20000000, LENGTH =  192k /* 192K sram */
    CCM (rw) : ORIGIN = 0x10000000, LENGTH =  64k  /* 64K ccm sram */
}
ENTRY(Reset_Handler)
_system_stack_size = 0x400;

SECTIONS
{
    .text :
    {
        . = ALIGN(4);
        _stext = .;
        KEEP(*(.isr_vector))            /* Startup code */

/* section information for finsh shell */
        . = ALIGN(4);
        __fsymtab_start = .;
        KEEP(*(FSymTab))
        __fsymtab_end = .;

. = ALIGN(4);
        __vsymtab_start = .;
        KEEP(*(VSymTab))
        __vsymtab_end = .;

/* section information for utest */
        . = ALIGN(4);
        __rt_utest_tc_tab_start = .;
        KEEP(*(UtestTcTab))
        __rt_utest_tc_tab_end = .;

/* section information for at server */
        . = ALIGN(4);
        __rtatcmdtab_start = .;
        KEEP(*(RtAtCmdTab))
        __rtatcmdtab_end = .;
        . = ALIGN(4);

/* section information for initial. */
        . = ALIGN(4);
        __rt_init_start = .;
        KEEP(*(SORT(.rti_fn*)))
        __rt_init_end = .;

. = ALIGN(4);

PROVIDE(__ctors_start__ = .);
        KEEP (*(SORT(.init_array.*)))
        KEEP (*(.init_array))
        PROVIDE(__ctors_end__ = .);

. = ALIGN(4);

_etext = .;
    } > ROM = 0

/* .ARM.exidx is sorted, so has to go in its own output section.  */
    __exidx_start = .;
    .ARM.exidx :
    {
        *(.ARM.exidx* .gnu.linkonce.armexidx.*)

/* This is used by the startup in order to initialize the .data secion */
/*_sidata = .;*/
    } > ROM
    __exidx_end = .;

.ccmbss (NOLOAD):
{
    . = ALIGN(4);
    _sccmbss = .;   /*create a global symbol at ccmram start */
    *(.ccmbss)      /* .data sections */
    *(.ccmbss*)     /* .data* sections */
    . = ALIGN(4);
    _eccmbss = .;  /*create a global symbol at ccmram end */
} >CCM

/* .data section which is used for initialized data */
_sidata = LOADADDR(.data);
.data :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _sdata = . ;

*(.data)
        *(.data.*)
        *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
        KEEP(*(SORT(.dtors.*)))
        KEEP(*(.dtors))
        PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _edata = . ;
    } >RAM AT > ROM
    
    .stack : 
    {
        . = ALIGN(4);
        _sstack = .;
        . = . + _system_stack_size;
        . = ALIGN(4);
        _estack = .;
    } >RAM

__bss_start = .;
    .bss :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _sbss = .;

*(.bss)
        *(.bss.*)
        *(COMMON)

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _ebss = . ;
        
        *(.bss.init)
    } > RAM
    __bss_end = .;

_end = .;

```

** 第三种方案完整main.c文件**

```c
#include <rtthread.h>

#define DBG_TAG "main"
#define DBG_LVL DBG_LOG
#include <rtdbg.h>

/*ccm .data*/
__attribute__((section(".ccm"))) rt_uint8_t array[4] = {1,2,3,4};
__attribute__((section(".ccm"))) rt_uint8_t *ptr = array;

/*ccm .bss*/
__attribute__((section(".ccmbss"))) rt_uint8_t bigger_array[10*1024];

/*.data*/
rt_uint8_t data_array[4] = {7,8,9,10};

int main(void)
{
    ptr = array;

rt_kprintf("ptr = 0x%08x, stores in 0x%08x\n", ptr, &ptr);

for(rt_uint8_t i = 0; i < 4; i++)
    {
        bigger_array[i] = i;
        rt_kprintf("array[%d] = %d\n",
                i,array[i]);
        rt_kprintf("bigger_array[%d] = %d\n",
                i,bigger_array[i]);
        rt_kprintf("data_array[%d] = %d\n",
                i,data_array[i]);
    }

return RT_EOK;
}

```

** 第三种方案结果**

![screenshot_image.png](https://oss-club.rt-thread.org/uploads/20230426/d0e785c77d9c3393fca386c2fb42f0dd.png.webp)

祝顺利！