关于renesas M16C分支的一点移植说明

发布于 2011-09-02 15:50:10 浏览：3322 订阅该版

在SVN r1687中context_iar.asm 
```rt_hw_context_switch     
    CMP.W    #1,rt_thread_switch_interrput_flag     
    JEQ      jump1     
    MOV.W    #1,rt_thread_switch_interrput_flag     
    MOV.W    R0, rt_interrupt_from_thread 
jump1     
    MOV.W    R1, rt_interrupt_to_thread     
    INT      #0     
    RTS ```
rt_hw_context_switch()是任务级的上下文切换函数(通过非屏蔽的软件中断实现上下文切换)
而rt_thread_switch_interrput_flag是中断级上下文切换标志

显然在M16C的移植分支中，函数rt_hw_context_switch()里无需判断标志rt_thread_switch_interrput_flag(事实上此时该标志值为0)
因此可以简化函数rt_hw_context_switch()，提高效率
```rt_hw_context_switch        
    MOV.W    R0, rt_interrupt_from_thread 
    MOV.W    R1, rt_interrupt_to_thread     
    INT      #0     
    RTS ```
相应的非屏蔽软件中断0处理函数
```os_context_switch:     
    PUSHM    R0,R1,R2,R3,A0,A1,SB,FB     
    CMP.W    #0,rt_thread_switch_interrput_flag     
    JEQ      exit     
    MOV.W    #0, rt_thread_switch_interrput_flag     
    MOV.W    rt_interrupt_from_thread, A0     
    STC      ISP, [A0]         
    MOV.W    rt_interrupt_to_thread, A0     
    LDC      [A0], ISP 
exit     
    POPM     R0,R1,R2,R3,A0,A1,SB,FB                      
    REIT                                         ; Return from interrup```  
也可以去掉对rt_thread_switch_interrput_flag标志的判断语句，可简化为：
```os_context_switch:     
    PUSHM    R0,R1,R2,R3,A0,A1,SB,FB         
    MOV.W    rt_interrupt_from_thread, A0     
    STC      ISP, [A0]         
    MOV.W    rt_interrupt_to_thread, A0     
    LDC      [A0], ISP   
    POPM     R0,R1,R2,R3,A0,A1,SB,FB                      
    REIT                                         ; Return from interrup```

现在回头看任务级的上下文切换函数rt_hw_context_switch()，
```rt_hw_context_switch        
    MOV.W    R0, rt_interrupt_from_thread 
    MOV.W    R1, rt_interrupt_to_thread     
    INT      #0     
    RTS ```
貌似比以前简洁很多，效率也提高了一点

但其实存在很严重的问题，问题就出在参数传递过程中，代码里默认为R0是参数1，R1是参数2
殊不知，M16C IAR编译器函数参数并非是如此传递的，在IAR的文档《IAR C/C++ Compiler Reference Guide》第97页有这样的说明：
The normal calling convention
The registers A0,R0, and R2 are used as much as possible to pass paramenters.
The simple calling convention
Only the first paramater may be passed in a register, either in R0L, R0, or R2R0, depending on the size of the first parameter.

由此可见不同的calling convention，函数参数使用的寄存器也是不一样的，有的还需要压栈
我想到的解决方法是：用C语言来实现任务级的上下文切换函数rt_hw_context_switch()
```void rt_hw_context_switch(rt_uint32_t from, rt_uint32_t to)
{
    rt_interrupt_from_thread = from;
    rt_interrupt_to_thread = to;
    asm("INT #0");    
}```
同样道理，也应该用C语言来实现函数rt_hw_context_switch_interrupt()
```void rt_hw_context_switch_interrupt(rt_uint32_t from, rt_uint32_t to)
{
    if (rt_thread_switch_interrput_flag != 1)
    {
        rt_thread_switch_interrput_flag = 1;
        rt_interrupt_from_thread = from;        
    }
    rt_interrupt_to_thread = to;  
}```
如此一来，任何一种calling convention(normal/simple)或者任一优化级别(none, low, medium, high),都可以正确的执行上下文切换。