10 rtthread studio生成hex文件正常，bin文件太大

发布于 2021-02-27 15:12:01 浏览：3016 订阅该版

Jone 2021-02-27

写了还是懒

Jone 2021-02-27

写了还是懒

jimmykudo 2021-03-01

这家伙很懒，什么也没写！

Jone 2021-03-01

写了还是懒

Jone 2021-03-01

写了还是懒

jimmykudo 2021-03-01

这家伙很懒，什么也没写！

jimmykudo 2021-03-01

这家伙很懒，什么也没写！

Jone 2021-03-01

写了还是懒

justseller99 2021-06-03

这家伙很懒，什么也没写！

@Jone 我现在也遇到同样的问题，把stm32f407 的告诉ram 拿来用，修改了链接文件，这个怎么处理好
```c
/*
 * linker script for STM32F4xx with GNU ld
 * bernard.xiong 2009-10-14
 * flybreak      2018-11-19  Add support for RAM2
 */

/* Program Entry, set to mark it as "used" and avoid gc */
MEMORY
{
CODE (rx) : ORIGIN =0x08020000,LENGTH =896k
RAM1 (rw) : ORIGIN =0x20000000,LENGTH =128k
RAM2 (rw) : ORIGIN =0x10000000,LENGTH =64k
}
ENTRY(Reset_Handler)
_system_stack_size = 0x200;

SECTIONS
{
    .text :
    {
        . = ALIGN(4);
        _stext = .;
        KEEP(*(.isr_vector))            /* Startup code */

. = ALIGN(4);
        *(.text)                        /* remaining code */
        *(.text.*)                      /* remaining code */
        *(.rodata)                      /* read-only data (constants) */
        *(.rodata*)
        *(.glue_7)
        *(.glue_7t)
        *(.gnu.linkonce.t*)

/* section information for finsh shell */
        . = ALIGN(4);
        __fsymtab_start = .;
        KEEP(*(FSymTab))
        __fsymtab_end = .;

. = ALIGN(4);
        __vsymtab_start = .;
        KEEP(*(VSymTab))
        __vsymtab_end = .;

/* section information for initial. */
        . = ALIGN(4);
        __rt_init_start = .;
        KEEP(*(SORT(.rti_fn*)))
        __rt_init_end = .;

. = ALIGN(4);

PROVIDE(__ctors_start__ = .);
        KEEP (*(SORT(.init_array.*)))
        KEEP (*(.init_array))
        PROVIDE(__ctors_end__ = .);
        
        . = ALIGN(4);
        
        _etext = .;
    } > CODE = 0

/* .ARM.exidx is sorted, so has to go in its own output section.  */
    __exidx_start = .;
    .ARM.exidx :
    {
        *(.ARM.exidx* .gnu.linkonce.armexidx.*)

/* This is used by the startup in order to initialize the .data secion */
        _sidata = .;
    } > CODE
    __exidx_end = .;

/* .data section which is used for initialized data */
	
    _siccmram = LOADADDR(.ccmram);
    .ccmram :
    {
        . = ALIGN(4);
        _sccmram = . ;
        *(.ccmram)
        *(.ccmram*);		
        . = ALIGN(4);
 
        _eccmram = . ;
    } >RAM2

.data : AT (_sidata)
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _sdata = . ;

*(.data)
        *(.data.*)
        *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
        KEEP(*(SORT(.dtors.*)))
        KEEP(*(.dtors))
        PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _edata = . ;
    } >RAM1

.stack : 
    {
        . = ALIGN(4);
        _sstack = .;
        . = . + _system_stack_size;
        . = ALIGN(4);
        _estack = .;
    } >RAM1

__bss_start = .;
    .bss :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _sbss = .;

*(.bss)
        *(.bss.*)
        *(COMMON)

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _ebss = . ;
        
        *(.bss.init)
    } > RAM1
    __bss_end = .;

_end = .;

/* Stabs debugging sections.  */
    .stab          0 : { *(.stab) }
    .stabstr       0 : { *(.stabstr) }
    .stab.excl     0 : { *(.stab.excl) }
    .stab.exclstr  0 : { *(.stab.exclstr) }
    .stab.index    0 : { *(.stab.index) }
    .stab.indexstr 0 : { *(.stab.indexstr) }
    .comment       0 : { *(.comment) }
    /* DWARF debug sections.
     * Symbols in the DWARF debugging sections are relative to the beginning
     * of the section so we begin them at 0.  */
    /* DWARF 1 */
    .debug          0 : { *(.debug) }
    .line           0 : { *(.line) }
    /* GNU DWARF 1 extensions */
    .debug_srcinfo  0 : { *(.debug_srcinfo) }
    .debug_sfnames  0 : { *(.debug_sfnames) }
    /* DWARF 1.1 and DWARF 2 */
    .debug_aranges  0 : { *(.debug_aranges) }
    .debug_pubnames 0 : { *(.debug_pubnames) }
    /* DWARF 2 */
    .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
    .debug_abbrev   0 : { *(.debug_abbrev) }
    .debug_line     0 : { *(.debug_line) }
    .debug_frame    0 : { *(.debug_frame) }
    .debug_str      0 : { *(.debug_str) }
    .debug_loc      0 : { *(.debug_loc) }
    .debug_macinfo  0 : { *(.debug_macinfo) }
    /* SGI/MIPS DWARF 2 extensions */
    .debug_weaknames 0 : { *(.debug_weaknames) }
    .debug_funcnames 0 : { *(.debug_funcnames) }
    .debug_typenames 0 : { *(.debug_typenames) }
    .debug_varnames  0 : { *(.debug_varnames) }
}
```

zhkag 2021-06-24

这家伙很懒，什么也没写！

Jone 2021-06-26

写了还是懒

lchnu 2022-04-08

Witness, Understand, Skill

lchnu 2022-04-08

Witness, Understand, Skill

@Jone

我尝试了几种方案，搞定了，谢谢你提出的方案。
1. ld文件修改
修改后ld：

```c
/* .data section which is used for initialized data */
_sidata = LOADADDR(.data);
.data :
{
    . = ALIGN(4);
    /* This is used by the startup in order to initialize the .data secion */
    _sdata = . ;

*(.data)
    *(.data.*)
    *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
    KEEP(*(SORT(.dtors.*)))
    KEEP(*(.dtors))
    PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
    /* This is used by the startup in order to initialize the .data secion */
    _edata = . ;
} >RAM AT>ROM

_siccmram = LOADADDR(.ccmram);
.ccmram :
{
	. = ALIGN(4);
	_sccmram = .;  /*create a global symbol at ccmram start */
	*(.ccmram)     /* .data sections */
	*(.ccmram*)    /* .data* sections */
	*(.bss.ccmram) /* .bss sections */
	. = ALIGN(4);
	_eccmram = .; /*create a global symbol at ccmram end */
} >CCMRAM AT>ROM
```

2. startup.s文件修改

```asm
LoopCopyDataInit:
  ldr  r0, =_sdata
  ldr  r3, =_edata
  adds  r2, r0, r1
  cmp  r2, r3
  bcc  CopyDataInit

movs r1, #0
  b LoopCopyDataInitCCM
CopyDataInitCCM:
  ldr r3, =_siccmram
  ldr r3, [r3,r1]
  str r3, [r0,r1]
  adds r1, r1, #4

LoopCopyDataInitCCM:
  ldr r0, =_sccmram
  ldr r3, =_eccmram
  adds r2, r0, r1
  cmp r2, r3
  bcc CopyDataInitCCM

ldr  r2, =_sbss
  b  LoopFillZerobss
/* Zero fill the bss segment. */  
FillZerobss:
  movs  r3, #0
  str  r3, [r2], #4
    
LoopFillZerobss:
  ldr  r3, = _ebss
  cmp  r2, r3
  bcc  FillZerobss

```