STM32F4在RT-Thread Studio中使用CCM SRAM

发布于 2020-03-21 20:28:55 浏览：5221 订阅该版

[tocm]

STM32F4x有192KB的SRAM，其中128KB 在总线矩阵上，64KB的CCM RAM在专为CPU使用的数据总线上。RT-Thread Studio默认只能使用128KB，没法使用CCM SRAM。参考ST的AN4296文档，实现了CCM SRAM的使用，
**必须保证DMA或者其他不通过CPU可能访问到数据的不在CCM RAM里面**。
具体步骤如下：

## 一、配置文件修改
1. 通过设定CCM RAM 区域的起始地址与大小，在链接器文件（.ld）中定义新的区域
```c
MEMORY
{
    ROM (rx)            : ORIGIN = 0x08000000, LENGTH = 512k /* 512K flash */
    RAM (rw)            : ORIGIN = 0x20000000, LENGTH = 128k /* 128K sram */
    CCMRAM (xrw)  : ORIGIN = 0x10000000, LENGTH = 64k /* 64K ccm ram */
}
```
## 2. 在链接器中指明，
带有ccmram 属性的代码段必须放在CCM RAM 中
```c
    .stack : 
    {
        . = ALIGN(4);
        _sstack = .;
        . = . + _system_stack_size;
        . = ALIGN(4);
        _estack = .;
    } >RAM

_siccmram = LOADADDR(.ccmram);

/* CCM-RAM section 
 * 
 * IMPORTANT NOTE! 
 * If initialized variables will be placed in this section,
 * the startup code needs to be modified to copy the init-values.  
 */
    .ccmram :
    {
      . = ALIGN(4);
      _sccmram = .; /* create a global symbol at ccmram start */
      *(.ccmram)
      *(.ccmram*)
      . = ALIGN(4);

_eccmram = .; /* create a global symbol at ccmram end */
    } >CCMRAM

__bss_start = .;
    .bss :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _sbss = .;

*(.bss)
        *(.bss.*)
        *(COMMON)
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _ebss = . ;
        
        *(.bss.init)
    } > RAM
```
## 3. 修改启动文件
从而在启动时对数据进行初始化并放入CCM RAM （参见红色的代码行）：
```asm
/* Copy the data segment initializers from flash to SRAM */

movs  r1, #0
  b  LoopCopyDataInit

CopyDataInit:
  ldr  r3, =_sidata
  ldr  r3, [r3, r1]
  str  r3, [r0, r1]
  adds  r1, r1, #4
    
LoopCopyDataInit:
  ldr  r0, =_sdata
  ldr  r3, =_edata
  adds  r2, r0, r1
  cmp  r2, r3
  bcc  CopyDataInit
  
  movs  r1, #0
  b  LoopCopyDataInit1

CopyDataInit1:
  ldr  r3, =_siccmram
  ldr  r3, [r3, r1]
  str  r3, [r0, r1]
  adds  r1, r1, #4
    
LoopCopyDataInit1:
  ldr  r0, =_sccmram
  ldr  r3, =_eccmram
  adds  r2, r0, r1
  cmp  r2, r3
  bcc  CopyDataInit1

ldr  r2, =_sbss
  b  LoopFillZerobss
/* Zero fill the bss segment. */  
FillZerobss:
  movs  r3, #0
  str  r3, [r2], #4
```
## 二、具体应用

1. 通过在函数原型中添加属性关键字，将需要从CCM RAM 执行的代码放入.ccmram区段：
```c
void led08_draw_point(uint8_t x,uint8_t y,uint8_t t) __attribute__((section (".ccmram")));
```
2、从CCM RAM 执行文件
从CCM RAM 执行源文件意味着该文件所声明的全部函数均从CCM RAM 执行。

将文件放入CCM RAM，如下所示：
```c
 /* CCM-RAM section 
 * 
 * IMPORTANT NOTE! 
 * If initialized variables will be placed in this section,
 * the startup code needs to be modified to copy the init-values.  
 */
    .ccmram :
    {
      . = ALIGN(4);
      _sccmram = .; /* create a global symbol at ccmram start */
      *(.ccmram)
      *(.ccmram*)   
      ./rt-thread/components/finsh/cmd.o(*)
      ./rt-thread/components/finsh/finsh_heap.o(*)
      ./rt-thread/components/finsh/finsh_heap.o(*)
      ./rt-thread/components/finsh/finsh_vm.o(*)
      ./rt-thread/components/finsh/shell.o(*)
      ./rt-thread/components/finsh/finsh_error.o(*)
      ./rt-thread/components/finsh/msh.o(*)
      ./rt-thread/components/utilities/ulog/backend/console_be.o(*)
      ./rt-thread/components/utilities/ulog/ulog.o(*)
      . = ALIGN(4);
      _eccmram = .; /* create a global symbol at ccmram end */
    } >CCMRAM
```

3.从CCM RAM 执行库
将库放入CCM RAM，如下所示：
```c
    .ccmram :

{
      . = ALIGN(4);
      _sccmram = .; /* create a global symbol at ccmram start */
      *(.ccmram)
      *(.ccmram*)
      mylib.a(*)      
      . = ALIGN(4);
      _eccmram = .; /* create a global symbol at ccmram end */
    } >CCMRAM
```

7 个回答

sync 2020-04-17

这家伙很懒，什么也没写！

majianjia 2020-04-17

这家伙很懒，什么也没写！

armink 2020-04-18

这家伙很懒，什么也没写！

williammyq 2020-07-27

这家伙很懒，什么也没写！

jimmykudo 2020-12-07

这家伙很懒，什么也没写！

lazyguoguo 2021-06-16

这家伙很懒，什么也没写！

lazyguoguo 2021-06-16

这家伙很懒，什么也没写！

直接这样做的话，bin文件生成巨大！！！
大概原因参考：https://www.cnblogs.com/RegressionWorldLine/p/11968467.html
根据上面文章 将ld文件改成：
```c
/*
 * linker script for STM32F407VE with GNU ld
 */

/* Program Entry, set to mark it as "used" and avoid gc */
MEMORY
{
ROM (rx) : ORIGIN =0x08020000,LENGTH =384k
RAM (rw) : ORIGIN =0x20000000,LENGTH =128k
CCMRAM (rw)  : ORIGIN = 0x10000000, LENGTH = 64k /* 64K ccm ram */
}
ENTRY(Reset_Handler)
_system_stack_size = 0x400;

SECTIONS
{
    .text :
    {
        . = ALIGN(4);
        _stext = .;
        KEEP(*(.isr_vector))            /* Startup code */

. = ALIGN(4);
        *(.text)                        /* remaining code */
        *(.text.*)                      /* remaining code */
        *(.rodata)                      /* read-only data (constants) */
        *(.rodata*)
        *(.glue_7)
        *(.glue_7t)
        *(.gnu.linkonce.t*)

/* section information for finsh shell */
        . = ALIGN(4);
        __fsymtab_start = .;
        KEEP(*(FSymTab))
        __fsymtab_end = .;

. = ALIGN(4);
        __vsymtab_start = .;
        KEEP(*(VSymTab))
        __vsymtab_end = .;

/* section information for utest */
        . = ALIGN(4);
        __rt_utest_tc_tab_start = .;
        KEEP(*(UtestTcTab))
        __rt_utest_tc_tab_end = .;

/* section information for at server */
        . = ALIGN(4);
        __rtatcmdtab_start = .;
        KEEP(*(RtAtCmdTab))
        __rtatcmdtab_end = .;
        . = ALIGN(4);

/* section information for initial. */
        . = ALIGN(4);
        __rt_init_start = .;
        KEEP(*(SORT(.rti_fn*)))
        __rt_init_end = .;

. = ALIGN(4);

PROVIDE(__ctors_start__ = .);
        KEEP (*(SORT(.init_array.*)))
        KEEP (*(.init_array))
        PROVIDE(__ctors_end__ = .);

. = ALIGN(4);

_etext = .;
    } > ROM = 0

/* .ARM.exidx is sorted, so has to go in its own output section.  */
    __exidx_start = .;
    .ARM.exidx :
    {
        *(.ARM.exidx* .gnu.linkonce.armexidx.*)

/* This is used by the startup in order to initialize the .data secion */
        _sidata = .;
    } > ROM
    __exidx_end = .;

/* .data section which is used for initialized data */

_sidata = LOADADDR(.data);
    .data :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _sdata = . ;

*(.data)
        *(.data.*)
        *(.gnu.linkonce.d*)

PROVIDE(__dtors_start__ = .);
        KEEP(*(SORT(.dtors.*)))
        KEEP(*(.dtors))
        PROVIDE(__dtors_end__ = .);

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .data secion */
        _edata = . ;
    } >RAM AT>ROM

_siccmram = LOADADDR(.ccmram);

/* CCM-RAM section 
	 * 
	 * IMPORTANT NOTE! 
	 * If initialized variables will be placed in this section,
	 * the startup code needs to be modified to copy the init-values.  
	 */
	.ccmram :
	{
	  . = ALIGN(4);
	  _sccmram = .; /* create a global symbol at ccmram start */
	  *(.ccmram)
      *(.ccmram*)
	  . = ALIGN(4);

_eccmram = .; /* create a global symbol at ccmram end */
	} >CCMRAM AT>ROM

.stack : 
	{
		. = ALIGN(4);
		_sstack = .;
		. = . + _system_stack_size;
		. = ALIGN(4);
		_estack = .;
	} >RAM

__bss_start = .;
    .bss :
    {
        . = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _sbss = .;

*(.bss)
        *(.bss.*)
        *(COMMON)

. = ALIGN(4);
        /* This is used by the startup in order to initialize the .bss secion */
        _ebss = . ;
        
        *(.bss.init)
    } > RAM
    __bss_end = .;

_end = .;

/* Stabs debugging sections.  */
    .stab          0 : { *(.stab) }
    .stabstr       0 : { *(.stabstr) }
    .stab.excl     0 : { *(.stab.excl) }
    .stab.exclstr  0 : { *(.stab.exclstr) }
    .stab.index    0 : { *(.stab.index) }
    .stab.indexstr 0 : { *(.stab.indexstr) }
    .comment       0 : { *(.comment) }
    /* DWARF debug sections.
     * Symbols in the DWARF debugging sections are relative to the beginning
     * of the section so we begin them at 0.  */
    /* DWARF 1 */
    .debug          0 : { *(.debug) }
    .line           0 : { *(.line) }
    /* GNU DWARF 1 extensions */
    .debug_srcinfo  0 : { *(.debug_srcinfo) }
    .debug_sfnames  0 : { *(.debug_sfnames) }
    /* DWARF 1.1 and DWARF 2 */
    .debug_aranges  0 : { *(.debug_aranges) }
    .debug_pubnames 0 : { *(.debug_pubnames) }
    /* DWARF 2 */
    .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
    .debug_abbrev   0 : { *(.debug_abbrev) }
    .debug_line     0 : { *(.debug_line) }
    .debug_frame    0 : { *(.debug_frame) }
    .debug_str      0 : { *(.debug_str) }
    .debug_loc      0 : { *(.debug_loc) }
    .debug_macinfo  0 : { *(.debug_macinfo) }
    /* SGI/MIPS DWARF 2 extensions */
    .debug_weaknames 0 : { *(.debug_weaknames) }
    .debug_funcnames 0 : { *(.debug_funcnames) }
    .debug_typenames 0 : { *(.debug_typenames) }
    .debug_varnames  0 : { *(.debug_varnames) }
}
```