IRQ thread

rtthread在线程执行过程中，被中断打断后进入中断处理时，是否有保护FPU的状态

发布于 2025-02-26 17:22:13 浏览：338 订阅该版

rtthread 3.1.3版本
程序实现的是正弦波的计算输出，在运行过程中，为了保证执行效率，会在中断中进行当前幅值输出的计算；
同时在运行过程中会接收界面下传的新一个幅值的数据，接收的新幅值数据会先进行一些补偿校正计算，
然后在接收特定消息后在中断中进行切换，
新下传的幅值相同但是按0.1v递增；频率固定为50Hz，相位固定0°，-120°，120°，所有数据*10000放大，
其中会出现以下问题：
问题1、补偿计算得出的幅值数据偶尔是错误的

![screenshot_42b89e284f04fabf2a7b45231d21dde.png](https://oss-club.rt-thread.org/uploads/20250226/750683e1438fb243cc4e4393ae6d9f57.png)

![screenshot_8aba453ad353d966902bab8df86199b.png](https://oss-club.rt-thread.org/uploads/20250226/e7c43cba718ccd61a385b725249f0b86.png)
问题2、下传的幅值、频率偶尔其中数据与其他相不一样,怀疑数据被修改了；
但是程序通信是经过crc计算后验证一致才接收，否则程序报错并结束；
而且程序是在其他平台正常使用了几年的，因此不存在传输不一致的情况；
这个问题是移植到rk3568，使用amp方式，实时核使用rtthread才出现的。

![screenshot_59b589cdeec1b3dacba2b1f018336f1.png](https://oss-club.rt-thread.org/uploads/20250226/bd988573ad480574735aa82aa8dd94f0.png)

![screenshot_a8ce89f48b7acf1f1a53c343f3180b5.png](https://oss-club.rt-thread.org/uploads/20250226/fe9e5ca42ba39878c1cbd614500a2aa5.png)

进行的一些尝试后发现：
    关闭FPU的使用，程序没有出现上面【问题1】的情况，但是由于没有硬件浮点运算支持，
性能不足导致出现丢点情况。怀疑是rtthread在进行中断切换时，没有对FPU寄存器进行保护。
【问题2】不知道什么原因造成的。
请问各位如何解决？

a1012112796 2025-03-03

这家伙很懒，什么也没写！

KevinLee 2025-04-25

这家伙很懒，什么也没写！

请登录后再发布评论，点击登录

追加回复

2 个回答

三世执戟 2025-02-26

这家伙很懒，什么也没写！

KevinLee 2025-02-26

这家伙很懒，什么也没写！

你好，用的rk3568，搜索RT_USING_FPU，有3个文件使用到了

context_gcc.S

```c
/*
 * Copyright (c) 2006-2018, RT-Thread Development Team
 *
 * SPDX-License-Identifier: Apache-2.0
 *
 * Change Logs:
 * Date           Author       Notes
 * 2013-07-05     Bernard      the first version
 */

#include "rtconfig.h"
.section .text, "ax"

#ifdef RT_USING_SMP
#define rt_hw_interrupt_disable rt_hw_local_irq_disable
#define rt_hw_interrupt_enable  rt_hw_local_irq_enable
#endif

/*
 * rt_base_t rt_hw_interrupt_disable();
 */
.globl rt_hw_interrupt_disable
rt_hw_interrupt_disable:
    mrs r0, cpsr
    cpsid i
    bx  lr

/*
 * void rt_hw_interrupt_enable(rt_base_t level);
 */
.globl rt_hw_interrupt_enable
rt_hw_interrupt_enable:
    msr cpsr, r0
    bx  lr

/*
 * void rt_hw_context_switch_to(rt_uint32 to, struct rt_thread *to_thread);
 * r0 --> to (thread stack)
 * r1 --> to_thread
 */
.globl rt_hw_context_switch_to
rt_hw_context_switch_to:
    ldr sp, [r0]            @ get new task stack pointer

#ifdef RT_USING_SMP
    mov     r0, r1
    bl      rt_cpus_lock_status_restore
#endif /*RT_USING_SMP*/
    b       rt_hw_context_switch_exit

.section .bss.share.isr
_guest_switch_lvl:
    .word 0

.globl vmm_virq_update

.section .text.isr, "ax"
/*
 * void rt_hw_context_switch(rt_uint32 from, rt_uint32 to, struct rt_thread *to_thread);
 * r0 --> from (from_thread stack)
 * r1 --> to (to_thread stack)
 * r2 --> to_thread
 */
.globl rt_hw_context_switch
rt_hw_context_switch:
    stmfd   sp!, {lr}       @ push pc (lr should be pushed in place of PC)
    stmfd   sp!, {r0-r12, lr}   @ push lr & register file

mrs r4, cpsr
    tst lr, #0x01
    orrne r4, r4, #0x20     @ it's thumb code

stmfd sp!, {r4}         @ push cpsr

#ifdef RT_USING_LWP
    stmfd sp, {r13, r14}^   @ push usr_sp usr_lr
    sub sp, #8
#endif
#ifdef RT_USING_FPU
    /* fpu context */
    vmrs r6, fpexc
    tst  r6, #(1<<30)
    beq 1f
    vstmdb sp!, {d0-d15}
    vstmdb sp!, {d16-d31}
    vmrs r5, fpscr
    stmfd sp!, {r5}
1:
    stmfd sp!, {r6}
#endif

str sp, [r0]            @ store sp in preempted tasks TCB
    ldr sp, [r1]            @ get new task stack pointer

#ifdef RT_USING_SMP
    mov     r0, r2
    bl      rt_cpus_lock_status_restore
#endif /*RT_USING_SMP*/
    b       rt_hw_context_switch_exit

/*
 * void rt_hw_context_switch_interrupt(rt_uint32 from, rt_uint32 to);
 */
.equ Mode_USR,        0x10
.equ Mode_FIQ,        0x11
.equ Mode_IRQ,        0x12
.equ Mode_SVC,        0x13
.equ Mode_ABT,        0x17
.equ Mode_UND,        0x1B
.equ Mode_SYS,        0x1F

.equ I_Bit,           0x80            @ when I bit is set, IRQ is disabled
.equ F_Bit,           0x40            @ when F bit is set, FIQ is disabled

.globl rt_thread_switch_interrupt_flag
.globl rt_interrupt_from_thread
.globl rt_interrupt_to_thread
.globl rt_hw_context_switch_interrupt
rt_hw_context_switch_interrupt:
#ifdef RT_USING_SMP
    /* r0 :svc_mod context
     * r1 :addr of from_thread's sp
     * r2 :addr of to_thread's sp
     * r3 :to_thread's tcb
     */

str     r0, [r1]

ldr     sp, [r2]
    mov     r0, r3
    bl      rt_cpus_lock_status_restore

b       rt_hw_context_switch_exit

#else /*RT_USING_SMP*/
    ldr r2, =rt_thread_switch_interrupt_flag
    ldr r3, [r2]
    cmp r3, #1
    beq _reswitch
    ldr ip, =rt_interrupt_from_thread   @ set rt_interrupt_from_thread
    mov r3, #1              @ set rt_thread_switch_interrupt_flag to 1
    str r0, [ip]
    str r3, [r2]
_reswitch:
    ldr r2, =rt_interrupt_to_thread     @ set rt_interrupt_to_thread
    str r1, [r2]
    bx  lr
#endif /*RT_USING_SMP*/

.global rt_hw_context_switch_exit
rt_hw_context_switch_exit:

#ifdef RT_USING_SMP
#ifdef RT_USING_SIGNALS
    mov     r0, sp
    cps #Mode_IRQ
    bl      rt_signal_check
    cps #Mode_SVC
    mov     sp, r0
#endif
#endif
#ifdef RT_USING_FPU
/* fpu context */
    ldmfd sp!, {r6}
    vmsr fpexc, r6
    tst  r6, #(1<<30)
    beq 1f
    ldmfd sp!, {r5}
    vmsr fpscr, r5
    vldmia sp!, {d16-d31}
    vldmia sp!, {d0-d15}
1:
#endif

#ifdef RT_USING_LWP
    ldmfd   sp, {r13, r14}^ /* usr_sp, usr_lr */
    add     sp, #8
#endif
    ldmfd   sp!, {r1}
    msr     spsr_cxsf, r1        /* original mode */
    ldmfd   sp!, {r0-r12,lr,pc}^ /* irq return */

```

start_gcc.S (9 matches)